EventConfigurator/apps/CMakeLists.txt

cmake_minimum_required(VERSION 3.19)
project(EventConfigurator LANGUAGES CXX)

find_package(Qt6 6.5 REQUIRED COMPONENTS Core Widgets)

set(CMAKE_AUTOUIC_SEARCH_PATHS "ui")

qt_standard_project_setup()

set(H_HEADER_FILES
    include/mainwindow.h
    include/logger.h
    include/settings.h
)

set(CPP_SOURCE_FILES
    source/main.cpp
    source/mainwindow.cpp
    source/logger.cpp
    source/settings.cpp
)

set(UI_FILES
    ui/mainwindow.ui
)

qt_add_executable(EventConfigurator
    WIN32 MACOSX_BUNDLE
    ${H_HEADER_FILES}
    ${CPP_SOURCE_FILES}
    ${UI_FILES}
)

target_include_directories(EventConfigurator PRIVATE "${CMAKE_CURRENT_SOURCE_DIR}/include")
target_link_libraries(EventConfigurator
    PRIVATE
        Qt::Core
        Qt::Widgets
)

include(GNUInstallDirs)

install(TARGETS EventConfigurator
    BUNDLE  DESTINATION .
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
)

qt_generate_deploy_app_script(
    TARGET EventConfigurator
    OUTPUT_SCRIPT deploy_script
    NO_UNSUPPORTED_PLATFORM_ERROR
)
install(SCRIPT ${deploy_script})